a) Tom A.  
b) raugost@yahoo.com
c) http://www.geocities.com/gossamerpenguin/
d) commented listing 

#local c=rgbt 1; 		// basic "clear" color, also useful for converting
                                // other vectors into color objects
#local i=99; 			// going to need this later
light_source{y*i c}		// but can use i to save a byte here.  
				// light used to create shadows, and make normals stand out
#macro q(l,w,r)			// the sea surface and sea floor plane
  plane{y,l 			
    normal{waves}		// give it shape
    pigment{c*w} 		// and color
    finish{reflection r/9 	// make it reflective, if surface
           ambient.3}		// make it brighter
    hollow 			// allow fog
    no_shadow}			// and let shadows through the sea surface
#end

#macro f(s)			// the fins
  disc{0,z,.5 			// just a disk 
       clipped_by{sphere{x,1}}	// clipped by a sphere
       translate s		// and moved depending on what type of fin
  }
#end

union{				// the school of bozo fish
  #while(i>1)			// lots of them
    union{			// an individual fish
       lathe{			// body shape is lathed
          cubic_spline 6,
            v-u,
            v,
            <.3,.5>,
            u/5,
            -v,
            -2*v 
          rotate-90*z		// turned on side to look fishlike
       }
       f(0)			// dorsal & ventral fins
       f(-x)			// tail fins
       rotate-y*i*5 		// "random" rotation
       translate<sin(i)*9,cos(i*9)*9,i> // "random" placement
    }				// end of individual fish object
    #local i=i-.2;
  #end   pigment{bozo scale.4}		// where the bozo fish gets its name
  finish{phong.4 ambient.3}	// to make it look a little better
				// the finish and pigment could have
				// gone on the individual fish, which 
				// would have made them all the same
				// pattern.  
}				// end of school

q(-3,.9,0)			// the sea floor
fog{279 c*y/2}			// get rid of the horizon, green up the picture
q(9,<0,0,1,.4>,5)		// the sea surface - not as noticable with the 
				// camera angle reduced, but the blue sky is still
				// visible.
camera{angle 30}		// focus on the school - gets more fish closer to the camera
background{c*z}			// blue sky above the water
//tpa2

e)  The Bozo Fish live peacably in the POV Lagoon.  Famous for their "snowflake"
quality - ie. no two are the same - they are not good trouphy fish, and being eyeless,
they run into things a lot.  They don't taste very good, unless you are a Gradient Shark,
which couldn't fit in 500 bytes.  Elsewhere in the Lagoon are some neat brain corals, but 
they too, couldn't fit in the 500 bytes.

F) I SUBMIT TO THE STANDARD 10BEST.RAYTRACE.COM COPYRIGHT
STATEMENT.